// FLIGHT / A Gate to the Sanctuary '02.09
// By Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.5;
global_settings {
  max_trace_level 6
  assumed_gamma 2.2
  }

#include "functions.inc"

camera {
  location < 0, 0, -2.5>
  look_at <0.1, 1, 0>
  angle 100
  }

light_source {< -10, 50, -15> color rgb <1, 1, 1>}
light_source {<0, 0, 0> color rgb <0, 0.2, 1>}

#declare fn_Pigm = function {
  pigment {
    marble
    turbulence 0.05
    color_map {
      [0.33 color rgb 0]
      [1    color rgb 1]
      }
    }
  }

isosurface {
  function {z*z+x*x+y*y-10*fn_Pigm(z*2,x*2, y*2).gray*fn_Pigm(x*2,y*2, z*2).gray+1}
  max_gradient 80
  open
  contained_by {sphere {<0, 0, 0> 2.2}}
  texture {
    pigment {color rgb <1, 1, 1>}
    finish {
      ambient 0.1
      diffuse 1
      reflection 0.7
      specular 1
      roughness 0.02
      brilliance 1
      }
    scale 1/vlength(1)
    }
  rotate <0, 10, 0>
  no_shadow
  } 

#declare Ca=3;
#declare Cb=2;
#declare A=Ca/2;
#declare B=Cb/2;
    quartic { <
        1, 0, 0, 6*B, 2,   0, 2, 6, 0, -2-6*A+B*B,   0, 0, 6*B, 0, 0,
        2*B, 0, 2*B, 0, -6*B-2*A*B,   1, 0, 2, 6, 0,   -1-6*A, 0, 2, 0, -2-2*A,
        1, 0, -6-2*A, 0, 1+6*A+A*A
        >
      bounded_by { box { <-5,-5,-5> <5,5,5> } }
      texture {
        pigment { color rgb <1,1,1> }
        finish {
          reflection 0.4
          specular 0.5
          ambient 0.4
          phong 0.5
          diffuse 0.5
          }
        }
      no_shadow
      scale <0.01,0.01,0.005>
      rotate <60,80,-40> 
      translate <0.08,0.2, -2.3>
      }