// FLIGHT / Landing '02.09
// By Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.5;
global_settings {
  max_trace_level 8
  assumed_gamma 2.2
  }

#include "functions.inc"

camera {
  location <-0, 3, -12>
  angle 90
  look_at  <-0.3, 1.2, 0>
  }

light_source {<500, 1000, -500> rgb 1}

isosurface {
  function{y+0.001*z+0.0005*x-5/((x*x+z*z-70)*(x*x+z*z-65)+10)-2.6/((x-3)*(x-3)+(z+2)*(z+2)+0.6)-f_agate(x,y,z)*0.3*y}
  threshold 0
  contained_by {box {<-10,0,-10>,<10,12,9>}}
  max_gradient 30
  pigment {rgb <0.9,0.9,1>}
  texture {
    pigment {color rgb <0.8, 1, 0.9>}
    finish {
      ambient 0.2
      diffuse 0.7
      reflection 0.8
      brilliance 0.7
      }
    }
  rotate <0,0,-10>
  }

background { color rgb <0.05, 0.1, 0.2> }

fog {
  fog_type   2
  distance   500
  color      rgb <1, 1, 1>
  fog_offset 10
  fog_alt    2.0
  turbulence 0.8
  rotate     <0, 0, -10>
   }

#declare Ca=3;
#declare Cb=2;
#declare A=Ca/2;
#declare B=Cb/2;
    quartic { <
        1, 0, 0, 6*B, 2,   0, 2, 6, 0, -2-6*A+B*B,   0, 0, 6*B, 0, 0,
        2*B, 0, 2*B, 0, -6*B-2*A*B,   1, 0, 2, 6, 0,   -1-6*A, 0, 2, 0, -2-2*A,
        1, 0, -6-2*A, 0, 1+6*A+A*A
        >
      bounded_by { box { <-5,-5,-5> <5,5,5> } }
      texture {
        pigment { color rgb <1,1,1> }
        finish {
          reflection 0.4
          specular 0.5
          ambient 0.4
          phong 0.5
          diffuse 0.5
          }
        }
      no_shadow
      scale <0.7,0.7,0.5>
      rotate <60,120,-25> 
      translate <-5,5.5, -5.0>
      }