// FLIGHT / A Departure '02.09
// By Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.5;
global_settings {
  max_trace_level 6
  assumed_gamma 2.2
  }

#include "functions.inc"

camera {
  location < 0, 5,-10>
  look_at < 1.7, 1.3, 0>
  angle 60
  }

light_source {< 20, 30,-60> color rgb <1,1,1>}
light_source {< 0, 0, 0> color rgb <1,0.5,0>}

#declare fn_Pigm = function {
  pigment { crackle
    color_map {
      [0    color rgb 1]
      [0.01 color rgb 0]
      }
    }
  }

#declare fn_Pign = function {
  pigment { leopard
    color_map {
      [0.9 color rgb 1]
      [1 color rgb 0]
      }
    }
  }

isosurface {
  function { y*y*9+x*x+z*z-9-20*fn_Pigm(x*3, y*9, z*3).gray*fn_Pign(x, y*3, z).gray }
  max_gradient 100
  contained_by { sphere {<0, 0, 0> 30 } }
  texture {
    pigment { color rgbt <0.7, 0.9, 1, 0.9> }
    finish {
      ambient 0.1
      diffuse 0.7
      reflection 0.8
      brilliance 1
      }
    }
  scale 1.3 rotate <30, 60, 0>
  no_shadow
  }

#declare Ca = 3;
#declare Cb = 1.5;
#declare A = Ca/2;
#declare B = Cb/2;
    quartic { <
        1, 0, 0, 6*B, 2,   0, 2, 6, 0, -2-6*A+B*B,   0, 0, 6*B, 0, 0,
        2*B, 0, 2*B, 0, -6*B-2*A*B,   1, 0, 2, 6, 0,   -1-6*A, 0, 2, 0, -2-2*A,
        1, 0, -6-2*A, 0, 1+6*A+A*A
        >
      bounded_by { box { <-7,-7,-7> <7,7,7> } }
      texture {
        pigment { color rgb <1,1,1> }
        finish {
          reflection 0.4
          specular 0.5
          ambient 0.4
          phong 0.5
          diffuse 0.5
          }
        }
      no_shadow
      scale <0.02,0.02,0.01>
      rotate z*205 rotate <150,50,60> rotate x*-10
      translate <0.15,4.92, -9.6>
      }

background { color rgb <0.06, 0.1, 0.2> }