// FUNCTION - FUNCTIONS by ISOSURFACE / A Fruit '02.07
// By Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.5;
global_settings {
  max_trace_level 5
  assumed_gamma 2.2
  }

camera {
  location <0, 0, -9>
  look_at <0.1, 0.1, 0>
  angle 27
  }

light_source {<-10, 10, -10> color <0, 1, 0.3>}
light_source {<50, 150, 170> color rgb <1, 0.8, 0.5>}

isosurface {
  function {((y-0.5)*(y-0.5)/4+((x-0.2*y)*(x-0.2*y)/3+(z-0.1*y)*(z-0.1*y)/3)
            -pow(cos((y-0.5)/pi*1.8)*sin(y*pi*3-atan(z/x)*pi)*sin(atan(z/x)*
            pi*3+y*pi),2)-1)*((y+0.05*z*z+2.3)*(y+0.05*z*z+2.3)+x*x-0.0001)-0.1}
  threshold 0
  max_gradient 60
  contained_by {box {<-3, -4, -3>, <3, 3, 3>}}
  texture {
    pigment {color rgb <1, 0.8, 0>}
    finish {
      ambient 0.3
      diffuse 0.3
      reflection 0.5
      phong 1
      phong_size 10 
      specular 0.5
      roughness 0.02
      brilliance 0.5
      }
    }
    scale 1/vlength(1)
    rotate y*40 rotate z*160
    no_shadow
  }

background { color rgb <0, 0, 0.4> }